第８回 関数と微分
• 関数の定義
関数f(x) = x3−8xを定義するときはf:= x -> x^3 - 8*x;とします。解析 学で良く使われる関数の多くは組み込み関数となっています。
例：sin, cos, tan, arcsin, arccos, arctan, sinh, ..
• 極限
Limit( (f(2+h)-f(2))/h, h=0 );
value(%);
極限を求める方法で微分商から微分係数を求めることができます。
• 関数の微分
極限を用いて微分を求めるのも可能ですが、微分する命令があります。
g:= x -> x^3*(x^2-2);
D(g);
D(g)(2);
D(g)(-1);
• 式の微分
h:= 2*x^3 -4*x +1;
diff(h, x);
k:= cos(x^2)^3;
diff(k,x);
diff(k,x,x);
diff(k,x,x,x);
diff(k,x$3);
微分の応用は関数の増減を調べる、極大極小を調べることが代表的ですが、Maple では plot 命令でグラフの概形を得ることができるので、グラフを用いることが有効 です。
関数f(x) =x3−0.2x2−xの −1≤x≤1 でのグラフを描く。
f:= x -> x^3 - 0.2*x^2 - x; plot( f(x), x=-1..1 );
図より極大極小の存在がわかります。極大値を与えるx を求めるには−1≤x≤0 でf0(x) = 0の解を求めれば良いので
Df:=diff(f(x),x); xmax:=fsolve(Df=0, x, x=-1..0);
または
plot( diff(f(x),x), x=-1..0 );
と x の範囲を狭めることによって微分の零点を求めることもできます。
例 二つ以上の曲線を図示するには、関数をグループ化します。
f:=x^2-x; plot( {f, diff(f,x)}, x=0..2 );
関数f に対して接線の関数を定義し、点(−1,2) を通る接線を図示する。
f:=’f’;
tangent := (x,a) -> D(f)(a)*(x-a)+f(a);
f:= x -> 1/x;
sol := solve( tangent(-1,a)=2, a );
t1 := subs( a=sol[1], tangent(x,a) );
t2 := subs( a=sol[2], tangent(x,a) );
plot( {t1, t2, f(x)}, x=-2..3 );
plot( {t1, t2, f(x)}, x=-2..3, y=-4..6 );
関数f に対して法線の関数を定義し、関数とその法線を図示する。
normalline:=(x,a) -> -(x-a)/D(f)(a)+f(a);
f:= x -> sin(x);
plot({seq(normalline(x,a/15), a=-30..30), f(x)}, x=-Pi..Pi);
plot({seq(normalline(x,a/15), a=-30..30), f(x)}, x=-Pi..Pi, y=-5..5);
plot({seq(normalline(x,a/15), a=-30..30), f(x)}, x=-Pi..Pi, y=-5..5, color=blue);
plot({seq(normalline(x,a/15), a=-30..30), f(x)}, x=-Pi..Pi, y=-5..5, color=blue, axes=none);
plot 命令にオプションを付けることによって見やすい図にすることができます。
plot(tan(x), x = -2*Pi..2*Pi, y = -4..4, discont = true);
plot([sin(x), x-x^3/6], x=0..2, color=[red,blue], style=[point,line]);
plot(sin(x), x=0..infinity);
l := [[ n, sin(n)] $n=1..10];
plot(l, x=0..15, style=point, symbol=circle);
plot(l, x=0..15, style=line);
練習 次の関数のグラフの概形を描け.
(1) y= 4
x2−4 (2)y=x+ 1 x (3) y=x4logx (4)y=e−xsinx (5) y= 2
1 +e−x 練習次の関数の極大, 極小を調べよ.
(1)y= (x−a)1/3(2x−a)2/3 (2) y=x3−x (3)y=p
|2 +x|+p
|2−x| (4) y=e−xcosx (5)y=ex+e−x+ 2 cosx
練習以下の関数の第3,4階の微分を求めよ.
(1)y=x2ex (2) y= 1−x 1 +x (3)y= cos 2xcosx (4) y= 1
x3 −x (5)y=x−2logx
• 部分分数
有理式の部分分数展開は、微分積分において、非常に有用な武器です。
(x^5+1)/(x^4-x^2); convert( %, parfrac, x);
• 級数展開
Taylor 展開、Maclaurin 展開のことです。x = a での級数(series)展開が Taylor 展開でa = 0 のときが Maclaurin 展開でした。標準で６次のオーダー の近似です。
f := x -> sin(4*x)*cos(x);
series( f(x), x=0 );
p1 := convert( % , polynom);
Order := 12;
series( f(x), x=0 );
p2 := convert( % , polynom);
plot( {f(x), p1}, x=-1..1, -2..2, title="approximation");
plot( {f(x), p2}, x=-1..1, -2..2, title="approximation of order 12");
練習以下の関数の第n階の微分を求めよ(予想せよ).
(1)y=x2ex (2) y= 1−x 1 +x (3)y= cos 2xcosx (4) y= 1
x3 −x (5)y=x−2logx
練習次の関数の Maclaurin展開を求めよ.
(1)y= cosx (2)y= (1 +x)α (3)y= 1
1 +x−2x2 (4)y= cosh x (5)y= x7
x12−1 (6)y= arcsin x
